こんにちは。継続の錬金術士なおキーヌです。

ブログ毎日更新は210日目になります。

第２回「プレイヤーを色々な位置に動かしてみよう」にてループを使ってスプライトを継続的に動かす方法を学びました。

自動で動いてしまったらゲームにはならないので、今回は条件式を駆使してコントロールできるようにしてみましょう。

まずは4方向の移動にチャレンジしてみます。4方向が出来たら後は斜めに移動させるだけで8方向移動が完成しますね。

それではプチコン4でSTG作りその第３回目始めましょう。

1. 押されているボタンを調べてみよう
2. 押されてるボタンに対して条件分岐をしてみよう
3. 押された方向にキャラクターを動かしてみよう
4. シューティングゲーム作り講座第３回まとめ

押されているボタンを調べてみよう

ACLS
' ボタンの状態を格納する変数
var B

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  PRINT B

  VSYNC
endloop

'ボタンに対応するビットをONにした値を作るには、1をボタンIDだけ左シフト(<<)すれば良い
'たとえば#B_RLEFTが押されているか調べたい場合 
BTNBIT_RLEFT = 1 << #B_RLEFT

引用元
https://sup4.smilebasic.com/doku.php?id=reference:%E5%90%84%E7%A8%AE%E5%85%A5%E5%8A%9B

定数について学ぼう

2進数＆ビットについて少しだけ学ぼう

' 1は0001、一番右のビットだけ１になっていると良い表せる

' 0001 を　２ビットそのままずらすと以下になる

' 0100

' 0100　は　2進数で４となる

' 補足すると　0001を4ビットずらした場合は以下のようになる

' 0001 0000

' つまり１を4ビットずらすと16になる

' 更に補足すると　4bitしか扱えない機械だった場合左

' 0001 0000 左側の[0001]は扱えないので結果０となる

' 溢れてしまうことを「オーバーフロー」という

ACLS
' ボタンの状態を格納する変数
var B

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  PRINT BIN$(B)

  VSYNC
endloop

ACLS
' ボタンの状態を格納する変数
var B

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  if (B AND 1 << #B_RLEFT) != 0 then
    PRINT "Yボタンが押されたよ"
  else
    PRINT "Yボタンを押してね"
  endif

  VSYNC
endloop

2進数の話をすると長ったらしく数学のお勉強みたいな状態になってしまうので
省略したかったのですが、RPG講座のときよりもわかりやすくしたかったので噛み砕いて説明してみました。

私自身2進数の取り扱いを完全に理解したというわけではないので、
詳しく2進数について知りたい人はググって詳しく解説しているサイトをみてもらったほうがいいでしょう。

今回プチコン４でボタンの押されている状態がちょっと複雑になってしまっているのは
Switchのコントローラーが分離出来てしまうせいかなとも思っています。

BIGの時はもうちょっとシンプルに書けた気がするんですが内部的には結局は2進数なので
2進数について理解しておけばプログラミング言語が変わろうが変わらない部分です。

プログラミングをする上で２進数は理解しておいて損はないので、
プログラミングが少し上達したら2進数をしっかり学んでみてみるとより理解度が高まります。

押されてるボタンに対して条件分岐をしてみよう

ACLS

' ボタンの状態を格納する変数
var B

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  if (B AND 1 << #B_LUP) != 0 then
    PRINT "上"
  elseif  (B AND 1 << #B_LDOWN) != 0 then
    PRINT "下"
  elseif  (B AND 1 << #B_LLEFT) != 0 then
    PRINT "左"
  elseif  (B AND 1 << #B_LRIGHT) != 0 then
    PRINT "右"
  endif

  VSYNC
endloop

押された方向にキャラクターを動かしてみよう

ACLS
' ボタンの状態を格納する変数
var B
var X = 0
var Y = 0

' スプライトを定義
SPSET 0, 352

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  if (B AND 1 << #B_LUP) != 0 then
    DEC Y
    SPOPS 0, X, Y
  elseif  (B AND 1 << #B_LDOWN) != 0 then
    INC Y
    SPOPS 0, X, Y
  elseif  (B AND 1 << #B_LLEFT) != 0 then
    DEC X
    SPOPS 0, X, Y
  elseif  (B AND 1 << #B_LRIGHT) != 0 then
    INC X
    SPOPS 0, X, Y
  endif

  VSYNC
endloop

ACLS
' ボタンの状態を格納する変数
var B
var X = 0
var Y = 0

' スプライトを定義
SPSET 0, 352

' ループ開始
loop
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  B = Button(0)
  ' 押されているボタンの情報を表示
  if (B AND 1 << #B_LUP) != 0 then
    DEC Y
  elseif (B AND 1 << #B_LDOWN) != 0 then
    INC Y
  endif
  if (B AND 1 << #B_LLEFT) != 0 then
    DEC X
  elseif (B AND 1 << #B_LRIGHT) != 0 then
    INC X
  endif

  SPOPS 0, X, Y

  VSYNC
endloop

最後に分かりやすいようにPRINTで表示しつつ動かしてみました。

マユミちゃんのやったように無駄な記述を減らすのもプログラミングの1つの楽しみでもあります。

まずはリキくんのようにがむしゃらに書いて動かしてから、
無駄だなって思うところを削除して元々と同じ動きを維持すれば見やすいコードになるしサイズも軽くなります。

今の時代のPCではあまり気にしなくてもいいですが、昔のパソコンは容量が少なかったので最適化は必須だったと思います。

しかし最適化しすぎて見にくいコードになってしまったら本末転倒ですから、何事もほどほどにしておきましょう。

それでは今回やったことをおさらいしてみましょう。

シューティングゲーム作り講座第３回まとめ

Button(n)

現在のボタンの状態を取得する関数。値を返してくれるので()を付けるのは必須です。

()の中のｎは数字を入力しましょう。コントローラー1の場合は0を指定します。

他にも特定のボタンだけを監視したり別コントローラーの監視をしたりできますが、詳しくは公式リファレンスを見てください

BIN$(n)

ｎに10進数の数字を与えると2進数の文字列に変換してくれます。

文字列として2進数で残したかったりする時に使うことが多いです。

＜＜ or ＞＞

ビットシフトです。「００１０」の状態で左にビットシフトを2回すると「１０００」になります。

二進数を理解していないと扱いが難しいので、今のところはあまり気にしなくても大丈夫です。

大文字で書いてますが半角英数で書いてください。

定数

一度決めたら変更できない入れ物。元々用意されている定数と、自分で用意することもできる。

自分で用意するときは頭にCONST を付けてから名前を「#」から始まる文字にしてください。

既に用意されている定数と被らないようにするためには公式リファレンスを確認しましょう。

DEC

INCの逆版。使い方は殆ど一緒で何も指定しないと1つ減らす。

if ~ elseif ~ endif

elseifを使うと条件式を複数作ることが出来る。

判断する順番はもちろん一番上からで手前のifの条件が満たない時に条件分岐が実行される。

自分でコントロールすることで一気にゲームに近づきました。

今回は2進数やビットシフト等、少し難しい内容が出てきましたが
トモカズくんの言うように仕組みそのものを完全に理解する必要は無く、道具をこうやって使えばこういう風に動くと覚えるのがベストです。

もし全然わからなかった場合はコードをそのまま打ち込んでどう動いているのか自分で調べると良いでしょう。

それでもわからなかった場合、とりあえず先に進めてみて再び戻ってきた時にすんなりと理解できるようになっているかもしれません。

次回は背景を表示してみましょう。真っ黒なままだと味気ないですからね。

宇宙空間っていう表現もありですけど学習のために背景を描写しましょう。

それでは。