こんにちは。なおキーヌです。

ブログ毎日更新は286日目になります。

ワンパク君を猪突猛進させるための移動処理の続きの記事になります。

前回、ワンパクくんとハカセの衝突を作るといったな。

アレはウソだ。

ってことで今回はヘビ役の神崎を地面から出現させる仕組みを作ります。

正直ワンパクくんでやったことの復習みたいなもんです。

というのも、もうインテリまで動きの基本処理を作ってからハカセ判定に移ろうと思いましたので……

それでは木こりゲーム作り第６回目、始めていきましょう。

1. 神崎の出現フラグを作る
2. 神崎を地面から地上に移動させる
3. 出現位置は基本的にはかせの真下

神崎の出現フラグを作る

ワンパクくんと同じように神崎のスプライト変数を設定しましょう。

ハカセを仕留められるのはワンパクくんと神崎だけなので、基本的には同じ変数をもっておけばOKです。

地面から攻撃してくるので向きは必要ないですね。

それでは準備しましょう

ワンパクくんと殆ど一緒なのでコメントは省きます。

SPSET 2, 1438, 0
SPCOL 2

SPVAR 2, "HIDE", 1
SPVAR 2, "X", 0
SPVAR 2, "Y", 240
SPVAR 2, "SPEED", 0
SPVAR 2, "DIRECT" , #FALSE
SPVAR 2, "DAMAGE", #FALSE

SPOFS 2, SPVAR(2,"X"),SPVAR(2,"Y")

ワンパクくんの処理を神崎のスプライト管理番号である「２」に置き換えただけです。

向きは変わりませんが、DIRECTは上下切り替えするために使用します。

あとは地面からくるので初期Y座標は画面外にしています。

X座標は出現時に決めるのでどこでもOKです。

後は衝突判定を行っているところは関数にして繰り返しを使いコードを簡略化しましょう。

少ないのでワンパクくん用と神崎用でコードを分けようと思いましたが、
簡単に省略出来たのでFORを使ってコンパクトにしてみました。

LOOP
  D_CONTROLLER

  ' 斧とハカセ以外のスプライトの判定を取る
  HITSP = SPHITSP(100,1,3)

  ' 敵の衝突制御
  ENEMY_COL_PROCESS

  ' 非表示敵の出現までのカウント
  HIDE_COUNT

  ' ワンパクくん移動処理
  WANPAKU_DASH

ENDLOOP



' エネミー判定処理
'───────────────────────────────
DEF ENEMY_COL_PROCESS
  FOR G_I = 0 TO 1
    IF HITSP == G_I && SPSHOW(G_I) == 1 THEN
      SPVAR G_I, "DAMAGE", #TRUE
      BEEP 120
    ENDIF
  NEXT
ENDIF

衝突判定はとれるようになったので、後は神崎を移動させて当てられるようにすればOKです。

神崎を地面から地上に移動させる

ワンパクくんは左右に移動しますが、神崎は基本的に上下にしか動きません。

X座標はハカセの真下に来るようにして邪魔するようにします。

出現までのフレーム数は一旦ワンパク君と同じにしておいて後で調整しましょう。

衝突判定は処理をまとめましたが、動きの処理はそれぞれ違うので別の関数にしておきます。

CONST #KANZAKI_MAXUP = 176

' 神崎移動関数
'───────────────────────────────
DEF KANZAKI_UPDOWN
  VAR SPID = 2
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DAMAGE") == #FALSE THEN
      IF SPVAR (SPID, "DIRECT") == #FALSE THEN
        SPVAR SPID, "Y", SPVAR(SPID, "Y") - SPVAR(SPID, "SPEED")
      ELSE
        SPVAR SPID, "Y", SPVAR(SPID, "Y") + 10
      ENDIF
    ELSE
      SPVAR SPID, "Y", SPVAR(SPID, "Y") +10
    ENDIF
  ENDIF
  SPOFS SPID, SPVAR(SPID, "X"), SPVAR(SPID, "Y")

  IF SPVAR(SPID, "Y") < #KANZAKI_MAXUP THEN
    SPVAR SPID, "DIRECT", #TRUE
  ENIDF 

  IF SPVAR(SPID, "Y") > 240+32 THEN
    SPVAR SPID, "HIDE", 1
    SPHIDE SPID
  ENDIF
ENDIF

基本上下移動だけなので、ワンパクくんよりシンプルに書けましたね。

後ワンパク君のときはスプライトIDを直接指定していましたが、今回はローカル変数を使って管理しました。

コチラの方があとでスプライトIDを変更した時に楽ですね。

ワンパクくんのほうも直しておくといいでしょう。

動きを説明すると、斧に当たったら問答無用でY座標を加算させて下にスライドさせ画面外に葬り去る。

それ以外は上に進み、最大値まで減算したら方向を切り替え地面に戻っていく。

シンプルですね。

何の特徴もない神崎らしいです。

出現位置は基本的にはかせの真下

出現フレームカウントが終わったらワンパクくんのように出現位置の設定をします。

神崎の場合はX座標の設定ですね。

基本的にはハカセのX座標＋16でいいでしょう。

LOOP
  D_CONTROLLER

  ' 斧とハカセ以外のスプライトの判定を取る
  HITSP = SPHITSP(100,1,3)

  ' 敵の衝突制御
  ENEMY_COL_PROCESS

  ' 非表示敵の出現までのカウント
  HIDE_COUNT

  ' ワンパクくん移動処理
  WANPAKU_DASH

  ' 神崎移動処理
  KANZAKI_UPDOWN
ENDLOOP


' 消滅時のカウント
'───────────────────────────────
DEF HIDE_COUNT
  VAR SP_WANPAKU = 1
  VAR SP_KANZAKI = 2

  IF SPVAR(SP_WANPAKU,"HIDE") >= 1 THEN
    SPVAR SP_WANPAKU, "HIDE", SPVAR(SP_WANPAKU, "HIDE")+1
    IF SPVAR(SP_WANPAKU, "HIDE") > #WANPAKU_POP THEN
      IF SPVAR(0,"X") < (400/2-1) THEN
        SPVAR SP_WANPAKU, "X", 400-16
        SPVAR SP_WANPAKU, "DIRECT", #TRUE
        SPCHR SP_WANPAKU, 128,352,32,32,#A_REVH

      ELSE
        SPVAR SP_WANPAKU, "X", -16
        SPVAR SP_WANPAKU, "DIRECT", #FALSE
        SPCHR SP_WANPAKU, 128,352,32,32,0
      ENDIF
      SPSHOW SP_WANPAKU
      SPVAR SP_WANPAKU, "DAMAGE", #FALSE
      SPVAR SP_WANPAKU, "Y", 160
      SPOFS SP_WANPAKU, SPVAR(SP_WANPAKU,"X"),SPVAR(SP_WANPAKU,"Y")
      SPVAR SP_WANPAKU, "SPEED", SPVAR(SP_WANPAKU,"SPEED") + 5
      SPVAR SP_WANPAKU, "HIDE", 0
    ENDIF
  ENDIF

  IF SPVAR(SP_KANZAKI,"HIDE") >= 1 THEN
    SPVAR SP_KANZAKI, "HIDE", SPVAR(SP_KANZAKI, "HIDE")+1
    IF SPVAR(1, "HIDE") > #WANPAKU_POP THEN

      SPVAR SP_KANZAKI, "X", SPVAR(0,"X")+16
      SPVAR SP_KANZAKI, "DIRECT", #FALSE
      SPVAR SP_KANZAKI, "DAMAGE", #FALSE

      SPVAR SP_KANZAKI, "Y", 240+32
      SPOFS SP_KANZAKI, SPVAR(SP_KANZAKI,"X"),SPVAR(SP_KANZAKI,"Y")
      SPVAR SP_KANZAKI, "SPEED", SPVAR(SP_KANZAKI,"SPEED") + 5
      SPVAR SP_KANZAKI, "HIDE", 0
      SPSHOW SP_KANZAKI
    ENDIF
  ENDIF
END

基本的に移動方向はY座標のマイナスなので処理がシンプルになりました。

これ、速度が上がってきたら避けられる感じがしませんね(笑)

一旦これで動かしてみましょう。

#petitcom #プチコン4 #NintendoSwitch

神崎ちょっとはやすぎたのでクソゲー pic.twitter.com/GLxVgSvVRE

— なおキーヌ＠ゲームクリエイターLv5 (@naokeyzmt) October 12, 2019

ACLS

' 地面と判定するための座標定数
CONST #GND = 160
' 神崎最大Y座標
CONST #KANZAKI_MAXUP = 176
' 出現までのフレーム数
CONST #WANPAKU_POP = 480


' ループ用変数
VAR G_I = 0
' 衝突判定用変数
VAR HITSP = -1
' ジャンプ配列アクセス用変数
VAR JPPC = 0
' ジャンプ配列
DIM JUMP_PROCESS[] = [-14,-10,-8,-6,-4,-2,2,4,6,8,10,14] 


' スプライト定義
SPSET 0, 1432
SPCOL 0
SPVAR 0, "X", 35
SPVAR 0, "Y", #GND
SPVAR 0, "DIRECT" , #FALSE
SPVAR 0, "SWING" , #FALSE
SPOFS 0, SPVAR(0,"X"), SPVAR(0,"Y")
SPVAR 0, "JUMP" , #FALSE

' 斧スプライト定義(非表示にしておく)
SPSET 100, 161, 0
SPCOL 100
SPVAR 100, "ROTATE", 0
' アトリビュートの基準点を変更
SPHOME 100, 8, 16



' その他スプライト定義
SPSET 3, 1442
SPOFS 3, 300,50
SPCOL 3


' ワンパクくんの初期を非表示に設定
SPSET 1, 1436, 0
SPCOL 1

' 開始時にカウント開始するために1を入れておく
SPVAR 1, "HIDE", 1
' ワンパク君の座標変数
SPVAR 1, "X", -16
SPVAR 1, "Y", 160
' ワンパク君の向き変数
SPVAR 1, "DIRECT", #FALSE
' ワンパク君のスピード(後で使う)
SPVAR 1, "SPEED", 0
' ワンパク君が斧に当たったかどうか
SPVAR 1, "DAMAGE", #FALSE

' ワンパク君の座標設定
SPOFS 1, SPVAR(1,"X"),SPVAR(1,"Y")

' 神崎スプライト設定
SPSET 2, 1438, 0
SPCOL 2
SPVAR 2, "HIDE", 1
SPVAR 2, "X", 0
SPVAR 2, "Y", 240
SPVAR 2, "SPEED", 0
SPVAR 2, "DIRECT" , #FALSE
SPVAR 2, "DAMAGE", #FALSE
SPOFS 2, SPVAR(2,"X"),SPVAR(2,"Y")



' 青空ぽい背景描写
FOR G_I=0 TO 240
  GLINE 0,I,400,I,RGB(I/2, 125+ROUND(I/2), 255)
NEXT

' 地面を描写
FOR G_I = 0 TO 24
  TPUT 0, G_I, 14, &HECC2
  TPUT 0, G_I, 14, &HED02
  TPUT 0, G_I, 14, &HED02
NEXT

LOOP
  D_CONTROLLER

  ' 斧とハカセ以外のスプライトの判定を取る
  HITSP = SPHITSP(100,1,3)

  ' 敵の衝突制御
  ENEMY_COL_PROCESS

  ' 非表示敵の出現までのカウント
  HIDE_COUNT

  ' ワンパクくん移動処理
  WANPAKU_DASH

  ' 神崎移動処理
  KANZAKI_UPDOWN

ENDLOOP



' コントローラー関数
'───────────────────────────────
DEF D_CONTROLLER
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  VAR B = BUTTON(0)

  ' 斧を振っていなかったら
  IF SPVAR(0,"SWING") == #FALSE THEN
    ' 左ボタン処理
    IF (B AND 1 << #B_LLEFT) != 0 THEN
      SPVAR 0, "X", SPVAR(0,"X")-1
      SPVAR 0, "DIRECT", #TRUE
    ENDIF

    ' 右ボタン処理
    IF (B AND 1 << #B_LRIGHT) != 0 THEN
      SPVAR 0, "X", SPVAR(0,"X")+1
      SPVAR 0, "DIRECT", #FALSE
    ENDIF

    ' 向き変更
    IF SPVAR(0, "DIRECT") == #TRUE THEN
      SPCHR 0,,,32,32,#A_REVH
      SPCHR 100,,,,,#A_REVH
      ' 向きに合わせて斧の位置を変える
      SPOFS 100, SPVAR(0,"X"), SPVAR(0,"Y")+24
    ELSE
      SPCHR 0,,,32,32,0
      SPCHR 100,,,,,0
      ' 向きに合わせて斧の位置を変える
      SPOFS 100, SPVAR(0,"X")-32, SPVAR(0,"Y")+24
    ENDIF

    ' 移動処理
    IF SPVAR(0,"X") < -16 THEN
      SPVAR 0,"X", -16
    ELSEIF SPVAR(0,"X") > 400-16 THEN
      SPVAR 0,"X", 400-16
    ENDIF
    SPOFS 0, SPVAR(0,"X"), SPVAR(0,"Y")

    ' Yボタン処理
    IF (B AND 1 << #B_LRIGHT) != 0 THEN
      ' 振った音を鳴らす
      BEEP 100

      ' ハカセのグラを変更
      IF SPVAR(0, "DIRECT") == #TRUE && SPVAR(0,"JUMP") != #TRUE THEN
        SPCHR 0,1433,,32,32,#A_REVH
      ELSE
        SPCHR 0,1433,,32,32,0
      ENDIF

      ' 斧振りフラグON
      SPVAR 0,"SWING", #TRUE
    ENDIF


    ' ジャンプ中か調べる
    IF SPVAR(0,"JUMP") != #TRUE THEN
      ' ジャンプ中じゃなければAボタン処理が効く
      IF (B AND 1 << #B_RRIGHT) != 0 THEN
        ' ジャンプフラグをONにする
        SPVAR 0,"JUMP", #TRUE
        ' 上昇中フラグに切り替える
        SPVAR 0,"UPDOWN", #TRUE
      ENDIF
    ELSE
      ' 現在座標にジャンプ配列の該当する値を取り出して足す
      SPVAR 0, "Y", SPVAR(0,"Y") + JUMP_PROCESS[JPPC]
      ' 次のジャンプ配列にアクセスするためにインクリメント
      INC JPPC
      ' もしアクセス変数と配列の長さが同じになったら
      IF JPPC == LEN(JUMP_PROCESS)-1 THEN 
        ' プレイヤーのY座標補正
        SPVAR 0, "Y", #GND
        ' ジャンプフラグを解除
        SPVAR 0,"JUMP", #FALSE
        ' 次のジャンプのためにアクセス変数を初期化しておく
        JPPC = 0
      ENDIF
    ENDIF


  ENDIF
END



' 斧振り関数
'───────────────────────────────
DEF D_SWING_AXE
  IF SPVAR(0,"SWING") == #TRUE THEN
    ' 斧を出現させる
    SPSHOW 100

    ' 向きによって振る方向を変更
    IF SPVAR(0, "DIRECT") == #TRUE THEN

      ' 斧を指定位置まで回転させる
      IF SPVAR(100, "ROTATE") > -90 THEN
        SPVAR 100, "ROTATE", SPVAR(100, "ROTATE")-5
        SPROT 100, SPVAR(100, "ROTATE")
      ELSE
        SPHIDE 100
        SPVAR 100, "ROTATE", 0
        SPROT 100, SPVAR(100, "ROTATE")
        SPVAR 0,"SWING", #FALSE
      ENDIF
    ELSE

      ' 斧を指定位置まで回転させる
      IF SPVAR(100, "ROTATE") < 90 THEN
        SPVAR 100, "ROTATE", SPVAR(100, "ROTATE")+5
        SPROT 100, SPVAR(100, "ROTATE")
      ELSE
        SPHIDE 100
        SPVAR 100, "ROTATE", 0
        SPROT 100, SPVAR(100, "ROTATE")
        SPVAR 0,"SWING", #FALSE
      ENDIF


    ENDIF

  ENDIF
END


' 消滅時のカウント
'───────────────────────────────
DEF HIDE_COUNT
  VAR SP_WANPAKU = 1
  VAR SP_KANZAKI = 2

  IF SPVAR(SP_WANPAKU,"HIDE") >= 1 THEN
    SPVAR SP_WANPAKU, "HIDE", SPVAR(SP_WANPAKU, "HIDE")+1
    IF SPVAR(SP_WANPAKU, "HIDE") > #WANPAKU_POP THEN
      IF SPVAR(0,"X") < (400/2-1) THEN
        SPVAR SP_WANPAKU, "X", 400-16
        SPVAR SP_WANPAKU, "DIRECT", #TRUE
        SPCHR SP_WANPAKU, 128,352,32,32,#A_REVH

      ELSE
        SPVAR SP_WANPAKU, "X", -16
        SPVAR SP_WANPAKU, "DIRECT", #FALSE
        SPCHR SP_WANPAKU, 128,352,32,32,0
      ENDIF
      SPSHOW SP_WANPAKU
      SPVAR SP_WANPAKU, "DAMAGE", #FALSE
      SPVAR SP_WANPAKU, "Y", 160
      SPOFS SP_WANPAKU, SPVAR(SP_WANPAKU,"X"),SPVAR(SP_WANPAKU,"Y")
      SPVAR SP_WANPAKU, "SPEED", SPVAR(SP_WANPAKU,"SPEED") + 5
      SPVAR SP_WANPAKU, "HIDE", 0
    ENDIF
  ENDIF

  IF SPVAR(SP_KANZAKI,"HIDE") >= 1 THEN
    SPVAR SP_KANZAKI, "HIDE", SPVAR(SP_KANZAKI, "HIDE")+1
    IF SPVAR(1, "HIDE") > #WANPAKU_POP THEN

      SPVAR SP_KANZAKI, "X", SPVAR(0,"X")+16
      SPVAR SP_KANZAKI, "DIRECT", #FALSE
      SPVAR SP_KANZAKI, "DAMAGE", #FALSE

      SPVAR SP_KANZAKI, "Y", 240+32
      SPOFS SP_KANZAKI, SPVAR(SP_KANZAKI,"X"),SPVAR(SP_KANZAKI,"Y")
      SPVAR SP_KANZAKI, "SPEED", SPVAR(SP_KANZAKI,"SPEED") + 5
      SPVAR SP_KANZAKI, "HIDE", 0
      SPSHOW SP_KANZAKI
    ENDIF
  ENDIF
END

' ワンパク君移動関数
'───────────────────────────────
DEF WANPAKU_DASH
  IF SPSHOW(1) == 1 THEN
    IF SPVAR (1, "DIRECT") == #FALSE THEN
      IF SPVAR (1, "DAMAGE") == #FALSE THEN
        SPVAR 1, "X", SPVAR(1, "X") + SPVAR(1, "SPEED")
      ELSE
        SPVAR 1, "X", SPVAR(1, "X") -10
        SPVAR 1, "Y", SPVAR(1, "Y") -10
      ENDIF
    ELSE
      IF SPVAR (1, "DAMAGE") == #FALSE THEN
        SPVAR 1, "X", SPVAR(1, "X") - SPVAR(1, "SPEED")
      ELSE
        SPVAR 1, "X", SPVAR(1, "X") +10
        SPVAR 1, "Y", SPVAR(1, "Y") -10
      ENDIF
    ENDIF
  ENDIF
  SPOFS 1, SPVAR(1, "X"), SPVAR(1, "Y")

  IF SPVAR(1, "X") > 400+32 || SPVAR(1, "X") < -32 THEN
    SPVAR 1, "HIDE", 1
    SPHIDE 1
  ENDIF

ENDIF

' 神崎移動関数
'───────────────────────────────
DEF KANZAKI_UPDOWN
  VAR SPID = 2
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DAMAGE") == #FALSE THEN
      IF SPVAR (SPID, "DIRECT") == #FALSE THEN
        SPVAR SPID, "Y", SPVAR(SPID, "Y") - SPVAR(SPID, "SPEED")
      ELSE
        SPVAR SPID, "Y", SPVAR(SPID, "Y") + 10
      ENDIF
    ELSE
      SPVAR SPID, "Y", SPVAR(SPID, "Y") +10
    ENDIF
  ENDIF
  SPOFS SPID, SPVAR(SPID, "X"), SPVAR(SPID, "Y")

  IF SPVAR(SPID, "Y") < #KANZAKI_MAXUP THEN
    SPVAR SPID, "DIRECT", #TRUE
  ENIDF 

  IF SPVAR(SPID, "Y") > 240+32 THEN
    SPVAR SPID, "HIDE", 1
    SPHIDE SPID
  ENDIF
ENDIF


' エネミー判定処理
'───────────────────────────────
DEF ENEMY_COL_PROCESS
  FOR G_I = 0 TO 1
    IF HITSP == G_I && SPSHOW(G_I) == 1 THEN
      SPVAR G_I, "DAMAGE", #TRUE
      BEEP 120
    ENDIF
  NEXT
ENDIF