【プチコン4講座】インテリはインテリらしく計算式で動かす

プチコン4 公開日:2019 10/13 | 最終更新日:2019 10/12

こんにちは。なおキーヌです。

ブログ毎日更新は287日目になります。

神崎を地面から出現させるの続きの記事になります。

ワンパクくんも神崎も動きを作ることが出来たので、
残りはインテリの動きを作ることですね。

インテリは鳥役なので基本的にハカセの攻撃は届きません。

なのでワンパクくんのように左右に動くだけです。

ワンパクくんとの違いは鳥なので上下にも移動するのですが、特に意味はありません。

インテリなのでインテリらしく計算式を使って上下させてみましょう。

そんな難しいことではなく、三角関数のSINを使うだけです。

それでは木こりゲーム作り第７回目、始めていきましょう。

インテリの出現フラグを作る
インテリを横移動させつつSIN関数で上下させる
出現位置は基本的にワンパクくんの使いまわし

インテリの出現フラグを作る

基本的にはワンパクくんの使いまわしで作って、上下運動だけを追加する感じです。

とりあえずインテリ用スプライト変数を調整してみましょう。

' インテリスプライト設定
SPSET 3, 1442, 0
SPCOL 3
SPVAR 3, "HIDE", 1
SPVAR 3, "X", 0
SPVAR 3, "Y", 50
SPVAR 3, "SPEED", 0
SPVAR 3, "DIRECT" , #FALSE
SPOFS 3, SPVAR(3,"X"),SPVAR(3,"Y")

基本的に同じですね。

FORを使って1つにまとめられそうです。

今は面倒なのでそのままでいきますが、気になる方はまとめてみてください。

インテリを横移動させつつSIN関数で上下させる

インテリはここからが本番です。

プログラミングにはSIN関数というサイン波(三角関数)が用意されていることが多いです。

コンピュータは元々計算機なので難しい計算式を使うものは、
プログラミング言語で内蔵されていることが多いです。

プチコン4ももちろんSIN関数があります。

角度(ラジアン)を渡すと値が返ってきます。

常に上下移動させたいので今回は一応SINを使ってやってインテリの上下運動を実装します。

一旦試しに上下だけ動かしてみましょう。

LOOP
  D_CONTROLLER

  ' 斧とハカセ以外のスプライトの判定を取る
  HITSP = SPHITSP(100,1,3)

  ' 敵の衝突制御
  ENEMY_COL_PROCESS

  ' 非表示敵の出現までのカウント
  HIDE_COUNT

  ' ワンパクくん移動処理
  WANPAKU_DASH

  ' 神崎移動処理
  KANZAKI_UPDOWN

  ' インテリ移動処理
  INTELI_FLOAT

ENDLOOP

' インテリ移動関数
'───────────────────────────────
DEF INTELI_FLOAT
  VAR SPID = 3
  SPVAR SPID, "SPEED", SPVAR(SPID,"SPEED")+0.05
  SPOFS SPID, SPVAR(SPID,"X"),SPVAR(SPID,"Y")+SIN(SPVAR(SPID,"SPEED")) * 30
END

INTELI MOVE

#petitcom #プチコン4 #NintendoSwitch pic.twitter.com/qWI228Shd9

— なおキーヌ＠ゲームクリエイターLv5 (@naokeyzmt) October 12, 2019

いい感じにSIN波で上下してくれています。

ゲームにおいてSIN波やCOS波は色んな用途で使えるので、調整に慣れておくとよいです。

シューティングのビームとかにも使えそうですね。

昔の横スクロールアクションの鳥の動きとかにもよく使われているので、今回インテリに適用しました。

出現位置は基本的にワンパクくんの使いまわし

後はワンパクくんと同じで左右に動かすだけです。

基本的には速度は固定でいいかなと思っています。

それでは早速実装してみましょう。

' インテリ移動関数
'───────────────────────────────
DEF INTELI_FLOAT
  SPID = 3
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DIRECT") == #FALSE THEN
      SPVAR SPID, "X", SPVAR(SPID, "X") + 1
    ELSE
      SPVAR SPID, "X", SPVAR(SPID, "X") - 1
    ENDIF

    SPVAR SPID, "SPEED", SPVAR(SPID,"SPEED")+0.05
    SPOFS SPID, SPVAR(SPID,"X"),SPVAR(SPID,"Y")+SIN(SPVAR(SPID,"SPEED")) * 30

    IF SPVAR(SPID, "X") > 400+32 || SPVAR(SPID, "X") < -32 THEN
      SPVAR SPID, "HIDE", 1
      SPHIDE SPID
    ENDIF
  ENDIF
END

移動処理はこんな感じでいいでしょう。
ワンパクくんの処理をほぼ流用しています。

ダメージ処理が無いので条件がシンプルですね。

次に再出現カウントも追加しましょう。

これもワンパクくんのほぼ使いまわしです。

うまくやればループで書けそうですが、一旦分離します。


' 消滅時のカウント
'───────────────────────────────
DEF HIDE_COUNT
  VAR SP_WANPAKU = 1
  VAR SP_KANZAKI = 2
  VAR SP_INTELI = 3

  ~~~ワンパク神崎省略~~~

  IF SPVAR(SP_INTELI,"HIDE") >= 1 THEN
    SPVAR SP_INTELI, "HIDE", SPVAR(SP_INTELI, "HIDE")+1
    IF SPVAR(SP_INTELI, "HIDE") > #WANPAKU_POP THEN
      IF SPVAR(0,"X") < (400/2-1) THEN
        SPVAR SP_INTELI, "X", 400-16
        SPVAR SP_INTELI, "DIRECT", #TRUE
        SPCHR SP_INTELI, 288,352,32,32,#A_REVH
      ELSE
        SPVAR SP_INTELI, "X", -16
        SPVAR SP_INTELI, "DIRECT", #FALSE
        SPCHR SP_INTELI, 288,352,32,32,0
      ENDIF
      SPSHOW SP_INTELI
      SPVAR SP_INTELI, "Y", 50
      SPOFS SP_INTELI, SPVAR(SP_INTELI,"X"),SPVAR(SP_INTELI,"Y")
      SPVAR SP_INTELI, "SPEED", 0
      SPVAR SP_INTELI, "HIDE", 0
    ENDIF
  ENDIF

END

変更点はスプライトナンバーと反転時のUV座標ぐらいでしょうか。

これでいい感じに全キャラ動けるようになりました。

実行してみましょう。

#petitcom #プチコン4 #NintendoSwitch

あふれでるクソゲー臭 pic.twitter.com/8gOd9Zvym0

— なおキーヌ＠ゲームクリエイターLv5 (@naokeyzmt) October 12, 2019

もう何のゲームかわからないですねこれ

きこり一切関係ない(笑)

次回はやっときこりらしいことをしようと思います。

樹木を生やして切れるようにしたいところです。

ACLS

' 地面と判定するための座標定数
CONST #GND = 160
' 神崎最大Y座標
CONST #KANZAKI_MAXUP = 176
' 出現までのフレーム数
CONST #WANPAKU_POP = 480


' ループ用変数
VAR G_I = 0
' 衝突判定用変数
VAR HITSP = -1
' ジャンプ配列アクセス用変数
VAR JPPC = 0
' ジャンプ配列
DIM JUMP_PROCESS[] = [-14,-10,-8,-6,-4,-2,2,4,6,8,10,14] 


' スプライト定義
SPSET 0, 1432
SPCOL 0
SPVAR 0, "X", 35
SPVAR 0, "Y", #GND
SPVAR 0, "DIRECT" , #FALSE
SPVAR 0, "SWING" , #FALSE
SPOFS 0, SPVAR(0,"X"), SPVAR(0,"Y")
SPVAR 0, "JUMP" , #FALSE

' 斧スプライト定義(非表示にしておく)
SPSET 100, 161, 0
SPCOL 100
SPVAR 100, "ROTATE", 0
' アトリビュートの基準点を変更
SPHOME 100, 8, 16






' ワンパクくんの初期を非表示に設定
SPSET 1, 1436, 0
SPCOL 1

' 開始時にカウント開始するために1を入れておく
SPVAR 1, "HIDE", 1
' ワンパク君の座標変数
SPVAR 1, "X", -16
SPVAR 1, "Y", 160
' ワンパク君の向き変数
SPVAR 1, "DIRECT", #FALSE
' ワンパク君のスピード(後で使う)
SPVAR 1, "SPEED", 0
' ワンパク君が斧に当たったかどうか
SPVAR 1, "DAMAGE", #FALSE

' ワンパク君の座標設定
SPOFS 1, SPVAR(1,"X"),SPVAR(1,"Y")

' 神崎スプライト設定
SPSET 2, 1438, 0
SPCOL 2
SPVAR 2, "HIDE", 1
SPVAR 2, "X", 0
SPVAR 2, "Y", 240
SPVAR 2, "SPEED", 0
SPVAR 2, "DIRECT" , #FALSE
SPVAR 2, "DAMAGE", #FALSE
SPOFS 2, SPVAR(2,"X"),SPVAR(2,"Y")


' インテリスプライト設定
SPSET 3, 1442, 0
SPCOL 3
SPVAR 3, "HIDE", 1
SPVAR 3, "X", 0
SPVAR 3, "Y", 50
SPVAR 3, "SPEED", 0
SPVAR 3, "DIRECT" , #FALSE
SPOFS 3, SPVAR(3,"X"),SPVAR(3,"Y")


' 青空ぽい背景描写
FOR G_I=0 TO 240
  GLINE 0,I,400,I,RGB(I/2, 125+ROUND(I/2), 255)
NEXT

' 地面を描写
FOR G_I = 0 TO 24
  TPUT 0, G_I, 14, &HECC2
  TPUT 0, G_I, 14, &HED02
  TPUT 0, G_I, 14, &HED02
NEXT

LOOP
  D_CONTROLLER

  ' 斧とハカセ以外のスプライトの判定を取る
  HITSP = SPHITSP(100,1,3)

  ' 敵の衝突制御
  ENEMY_COL_PROCESS

  ' 非表示敵の出現までのカウント
  HIDE_COUNT

  ' ワンパクくん移動処理
  WANPAKU_DASH

  ' 神崎移動処理
  KANZAKI_UPDOWN

  ' インテリ移動処理
  INTELI_FLOAT
ENDLOOP



' コントローラー関数
'───────────────────────────────
DEF D_CONTROLLER
  ' 0番目のコントローラー(つまり1コン)の押されているボタンを取得
  VAR B = BUTTON(0)

  ' 斧を振っていなかったら
  IF SPVAR(0,"SWING") == #FALSE THEN
    ' 左ボタン処理
    IF (B AND 1 << #B_LLEFT) != 0 THEN
      SPVAR 0, "X", SPVAR(0,"X")-1
      SPVAR 0, "DIRECT", #TRUE
    ENDIF

    ' 右ボタン処理
    IF (B AND 1 << #B_LRIGHT) != 0 THEN
      SPVAR 0, "X", SPVAR(0,"X")+1
      SPVAR 0, "DIRECT", #FALSE
    ENDIF

    ' 向き変更
    IF SPVAR(0, "DIRECT") == #TRUE THEN
      SPCHR 0,,,32,32,#A_REVH
      SPCHR 100,,,,,#A_REVH
      ' 向きに合わせて斧の位置を変える
      SPOFS 100, SPVAR(0,"X"), SPVAR(0,"Y")+24
    ELSE
      SPCHR 0,,,32,32,0
      SPCHR 100,,,,,0
      ' 向きに合わせて斧の位置を変える
      SPOFS 100, SPVAR(0,"X")-32, SPVAR(0,"Y")+24
    ENDIF

    ' 移動処理
    IF SPVAR(0,"X") < -16 THEN
      SPVAR 0,"X", -16
    ELSEIF SPVAR(0,"X") > 400-16 THEN
      SPVAR 0,"X", 400-16
    ENDIF
    SPOFS 0, SPVAR(0,"X"), SPVAR(0,"Y")

    ' Yボタン処理
    IF (B AND 1 << #B_LRIGHT) != 0 THEN
      ' 振った音を鳴らす
      BEEP 100

      ' ハカセのグラを変更
      IF SPVAR(0, "DIRECT") == #TRUE && SPVAR(0,"JUMP") != #TRUE THEN
        SPCHR 0,1433,,32,32,#A_REVH
      ELSE
        SPCHR 0,1433,,32,32,0
      ENDIF

      ' 斧振りフラグON
      SPVAR 0,"SWING", #TRUE
    ENDIF


    ' ジャンプ中か調べる
    IF SPVAR(0,"JUMP") != #TRUE THEN
      ' ジャンプ中じゃなければAボタン処理が効く
      IF (B AND 1 << #B_RRIGHT) != 0 THEN
        ' ジャンプフラグをONにする
        SPVAR 0,"JUMP", #TRUE
        ' 上昇中フラグに切り替える
        SPVAR 0,"UPDOWN", #TRUE
      ENDIF
    ELSE
      ' 現在座標にジャンプ配列の該当する値を取り出して足す
      SPVAR 0, "Y", SPVAR(0,"Y") + JUMP_PROCESS[JPPC]
      ' 次のジャンプ配列にアクセスするためにインクリメント
      INC JPPC
      ' もしアクセス変数と配列の長さが同じになったら
      IF JPPC == LEN(JUMP_PROCESS)-1 THEN 
        ' プレイヤーのY座標補正
        SPVAR 0, "Y", #GND
        ' ジャンプフラグを解除
        SPVAR 0,"JUMP", #FALSE
        ' 次のジャンプのためにアクセス変数を初期化しておく
        JPPC = 0
      ENDIF
    ENDIF


  ENDIF
END



' 斧振り関数
'───────────────────────────────
DEF D_SWING_AXE
  IF SPVAR(0,"SWING") == #TRUE THEN
    ' 斧を出現させる
    SPSHOW 100

    ' 向きによって振る方向を変更
    IF SPVAR(0, "DIRECT") == #TRUE THEN

      ' 斧を指定位置まで回転させる
      IF SPVAR(100, "ROTATE") > -90 THEN
        SPVAR 100, "ROTATE", SPVAR(100, "ROTATE")-5
        SPROT 100, SPVAR(100, "ROTATE")
      ELSE
        SPHIDE 100
        SPVAR 100, "ROTATE", 0
        SPROT 100, SPVAR(100, "ROTATE")
        SPVAR 0,"SWING", #FALSE
      ENDIF
    ELSE

      ' 斧を指定位置まで回転させる
      IF SPVAR(100, "ROTATE") < 90 THEN
        SPVAR 100, "ROTATE", SPVAR(100, "ROTATE")+5
        SPROT 100, SPVAR(100, "ROTATE")
      ELSE
        SPHIDE 100
        SPVAR 100, "ROTATE", 0
        SPROT 100, SPVAR(100, "ROTATE")
        SPVAR 0,"SWING", #FALSE
      ENDIF


    ENDIF

  ENDIF
END


' 消滅時のカウント
'───────────────────────────────
DEF HIDE_COUNT
  VAR SP_WANPAKU = 1
  VAR SP_KANZAKI = 2
  VAR SP_INTELI = 3

  IF SPVAR(SP_WANPAKU,"HIDE") >= 1 THEN
    SPVAR SP_WANPAKU, "HIDE", SPVAR(SP_WANPAKU, "HIDE")+1
    IF SPVAR(SP_WANPAKU, "HIDE") > #WANPAKU_POP THEN
      IF SPVAR(0,"X") < (400/2-1) THEN
        SPVAR SP_WANPAKU, "X", 400-16
        SPVAR SP_WANPAKU, "DIRECT", #TRUE
        SPCHR SP_WANPAKU, 128,352,32,32,#A_REVH

      ELSE
        SPVAR SP_WANPAKU, "X", -16
        SPVAR SP_WANPAKU, "DIRECT", #FALSE
        SPCHR SP_WANPAKU, 128,352,32,32,0
      ENDIF
      SPSHOW SP_WANPAKU
      SPVAR SP_WANPAKU, "DAMAGE", #FALSE
      SPVAR SP_WANPAKU, "Y", 160
      SPOFS SP_WANPAKU, SPVAR(SP_WANPAKU,"X"),SPVAR(SP_WANPAKU,"Y")
      SPVAR SP_WANPAKU, "SPEED", SPVAR(SP_WANPAKU,"SPEED") + 5
      SPVAR SP_WANPAKU, "HIDE", 0
    ENDIF
  ENDIF

  IF SPVAR(SP_KANZAKI,"HIDE") >= 1 THEN
    SPVAR SP_KANZAKI, "HIDE", SPVAR(SP_KANZAKI, "HIDE")+1
    IF SPVAR(1, "HIDE") > #WANPAKU_POP THEN

      SPVAR SP_KANZAKI, "X", SPVAR(0,"X")+16
      SPVAR SP_KANZAKI, "DIRECT", #FALSE
      SPVAR SP_KANZAKI, "DAMAGE", #FALSE

      SPVAR SP_KANZAKI, "Y", 240+32
      SPOFS SP_KANZAKI, SPVAR(SP_KANZAKI,"X"),SPVAR(SP_KANZAKI,"Y")
      SPVAR SP_KANZAKI, "SPEED", SPVAR(SP_KANZAKI,"SPEED") + 5
      SPVAR SP_KANZAKI, "HIDE", 0
      SPSHOW SP_KANZAKI
    ENDIF
  ENDIF

  IF SPVAR(SP_INTELI,"HIDE") >= 1 THEN
    SPVAR SP_INTELI, "HIDE", SPVAR(SP_INTELI, "HIDE")+1
    IF SPVAR(SP_INTELI, "HIDE") > #WANPAKU_POP THEN
      IF SPVAR(0,"X") < (400/2-1) THEN
        SPVAR SP_INTELI, "X", 400-16
        SPVAR SP_INTELI, "DIRECT", #TRUE
        SPCHR SP_INTELI, 288,352,32,32,#A_REVH
      ELSE
        SPVAR SP_INTELI, "X", -16
        SPVAR SP_INTELI, "DIRECT", #FALSE
        SPCHR SP_INTELI, 288,352,32,32,0
      ENDIF
      SPSHOW SP_INTELI
      SPVAR SP_INTELI, "Y", 50
      SPOFS SP_INTELI, SPVAR(SP_INTELI,"X"),SPVAR(SP_INTELI,"Y")
      SPVAR SP_INTELI, "SPEED", 0
      SPVAR SP_INTELI, "HIDE", 0
    ENDIF
  ENDIF

END

' ワンパク君移動関数
'───────────────────────────────
DEF WANPAKU_DASH
  SPID = 1
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DIRECT") == #FALSE THEN
      IF SPVAR (SPID, "DAMAGE") == #FALSE THEN
        SPVAR SPID, "X", SPVAR(SPID, "X") + SPVAR(SPID, "SPEED")
      ELSE
        SPVAR SPID, "X", SPVAR(SPID, "X") -10
        SPVAR SPID, "Y", SPVAR(SPID, "Y") -10
      ENDIF
    ELSE
      IF SPVAR (SPID, "DAMAGE") == #FALSE THEN
        SPVAR SPID, "X", SPVAR(SPID, "X") - SPVAR(SPID, "SPEED")
      ELSE
        SPVAR SPID, "X", SPVAR(SPID, "X") +10
        SPVAR SPID, "Y", SPVAR(SPID, "Y") -10
      ENDIF
    ENDIF
  ENDIF
  SPOFS SPID, SPVAR(SPID, "X"), SPVAR(SPID, "Y")

  IF SPVAR(SPID, "X") > 400+32 || SPVAR(SPID, "X") < -32 THEN
    SPVAR SPID, "HIDE", 1
    SPHIDE SPID
  ENDIF

END


' 神崎移動関数
'───────────────────────────────
DEF KANZAKI_UPDOWN
  VAR SPID = 2
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DAMAGE") == #FALSE THEN
      IF SPVAR (SPID, "DIRECT") == #FALSE THEN
        SPVAR SPID, "Y", SPVAR(SPID, "Y") - SPVAR(SPID, "SPEED")
      ELSE
        SPVAR SPID, "Y", SPVAR(SPID, "Y") + 10
      ENDIF
    ELSE
      SPVAR SPID, "Y", SPVAR(SPID, "Y") +10
    ENDIF
  ENDIF
  SPOFS SPID, SPVAR(SPID, "X"), SPVAR(SPID, "Y")

  IF SPVAR(SPID, "Y") < #KANZAKI_MAXUP THEN
    SPVAR SPID, "DIRECT", #TRUE
  ENIDF 

  IF SPVAR(SPID, "Y") > 240+32 THEN
    SPVAR SPID, "HIDE", 1
    SPHIDE SPID
  ENDIF
END

' インテリ移動関数
'───────────────────────────────
DEF INTELI_FLOAT
  SPID = 3
  IF SPSHOW(SPID) == 1 THEN
    IF SPVAR (SPID, "DIRECT") == #FALSE THEN
      SPVAR SPID, "X", SPVAR(SPID, "X") + 1
    ELSE
      SPVAR SPID, "X", SPVAR(SPID, "X") - 1
    ENDIF

    SPVAR SPID, "SPEED", SPVAR(SPID,"SPEED")+0.05
    SPOFS SPID, SPVAR(SPID,"X"),SPVAR(SPID,"Y")+SIN(SPVAR(SPID,"SPEED")) * 30

    IF SPVAR(SPID, "X") > 400+32 || SPVAR(SPID, "X") < -32 THEN
      SPVAR SPID, "HIDE", 1
      SPHIDE SPID
    ENDIF
  ENDIF
END


' エネミー判定処理
'───────────────────────────────
DEF ENEMY_COL_PROCESS
  FOR G_I = 0 TO 1
    IF HITSP == G_I && SPSHOW(G_I) == 1 THEN
      SPVAR G_I, "DAMAGE", #TRUE
      BEEP 120
    ENDIF
  NEXT
END

ゲームプログラミングレシピ集

【プチコン4講座】インテリはインテリらしく計算式で動かす

インテリの出現フラグを作る

インテリを横移動させつつSIN関数で上下させる

出現位置は基本的にワンパクくんの使いまわし

関連記事

【プチコン4講座】敵のスプライトを用意して動かそう

【プチコン4講座】斧とワンパク君に衝突判定を実装

【プチコン4講座】あっちむいてホイを作ろう：仕組み構築編

【プチコン4講座】アクションRPG風バトル構築：プレイヤー操作編

【プチコン4講座】キャラを中心に置いて背景をスクロールする方法

【プチコン4講座】LMATRIXの扱いは偏差値38未満には辛い件

【プチコン4講座】ボタンを押してゲージを溜める処理の作り方

【プチコン4講座】アクションゲームを作るためにスプライトを覚えよう